FTP gebruiken in een batchfile
Op deze pagina:
Om via een batchfile een bestand te uploaden naar een FTP-server maken we fileupload.bat:
@echo off
rem *** UserName vervangen door de gebruikersnaam:
echo user UserName> ftpcmd.dat
rem *** Password vervangen door het wachtwoord:
echo Password>> ftpcmd.dat
rem *** volgende regel is alleen nodig als
rem *** het pad aangepast moet worden
rem *** /pathname/ moet dan veranderd worden
rem *** in het gewenste pad op de FTP-server:
echo cd /pathname/>>ftpcmd.dat
rem *** volgende regel zet de transfermode
rem *** op binary:
echo binary>> ftpcmd.dat
rem *** volgende regel stuurt het bestand dat
rem *** als argument aan
rem *** de batchfile is meegegeven:
echo put %1>> ftpcmd.dat
rem *** eindigen:
echo quit>> ftpcmd.dat
rem *** de optie -n staat voor niet automatisch
rem *** inloggen, maar de gegevens uit
rem *** dit bestand gebruiken om in te loggen
rem *** de optie -s staat voor het gebruiken
rem *** van dit bestand voor
rem *** het lezen van de commando's
rem *** SERVERNAME.COM moet vervangen worden
rem *** door de naam van de FTP-server:
ftp -n -s:ftpcmd.dat SERVERNAME.COM
rem *** de volgende regel verwijdert het
rem *** aangemaakte (tijdelijke)
rem *** commandobestand na de FTP-upload:
del ftpcmd.dat
De batchfile kan nu aangeroepen worden met het bestand dat moet worden ge-upload (bijvoorbeeld TeUploadenBestand.zip) als argument:
fileupload TeUploadenBestand.zip